传说中神一样编辑器的Emacs向来以难学难用，喜欢折腾人著称。三天打渔两天晒网的我，居然心甘情愿地被它折腾了5，6年之久，期间苦乐不足为外人道也。

不过，以我的使用感觉，Emacs 更象是匹烈马：初时很难驾驭，可一旦征服，使用起来便得心应手，威力无穷。尽管被它折腾的不轻，但也因此学会了很多提高工作效率的小技巧。而在用 Emacs 编辑时更是可以做到心无旁骛，任由思路驰骋纵横在键盘间，达到一种所谓“流”的状态。

虽说如此，长久以来，还是有很多小细节让自己在使用Emacs的时候很是不爽，最近一周稍有闲暇，本着磨刀不误砍柴工的精神，也来折腾了一下 Emacs，居然被我搞定了几个困扰已久的配置。整理记录一下，希望能帮到遇到同样问题的朋友们。

Emacs 中文字体配置

这是最让我恼火的配置之一，在 Emacs 23 以前，由于底层不是 Unicode ，经常会遇到中文乱码的问题。好在 Emacs 23 中底层统一用 Unicode 重新实现了，现在不会再有乱码的问题，可是字体的配置却很麻烦，网上有很多的例子和文档，但都或多或少有些问题，总是不能尽善尽美。

最简单的字体设置方式是

(set-default-font "-outline-Lucida Console-normal-normal-normal-mono-*-*-*-*-*-*-iso10646-1" 1)

但它的问题是，该设置只对初始的窗口（ Frame ）有效，对于新窗口 (如speedbar，或用快捷键 Ctrl-x 5 2 分出来的窗口）无效。改成下面的设置方法，字体设置对初始窗口和后面的新窗口就都会生效了。

(setq default-frame-alist (font . "Lucida Console 12"))

还有个问题，就是对中英文混排文本的字体支持，简单的方法是使用同时包含中文和英文的字体。网上有好心人把中文和等宽英文字体合并为新的字体，方便编程使用。比如我以前配置里用的“微软雅黑Monaco”字体就很不错。

(setq default-frame-alist (font . "微软雅黑Monaco 12"))

这种方法的缺点在于，你没办法单独换英文字体或中文字体，只能新做一个字体整体换掉。另外，网上做的字体里面，并没有包含斜体，显示的时候不够丰富。

其实 Emacs 本身支持根据字符编码去找合适的字体，不过需要按编码详细的设置，让 Emacs 明白遇到汉字编码要用宋体，而不是楷体或“Lucida Console”。

1
2
3
4

(set-fontset-font
    (frame-parameter nil 'font)
    'han
    (font-spec :family "Microsoft Yahei" :size 12))

除了 han 以外，还有 kana, symbol, cjk-misc, bopomofo 这些编码集也要一并设置好。可以用 elisp 的 dolist 做循环操作，减少不必要的复制粘贴

1
2
3
4

(dolist (charset '(kana han symbol cjk-misc bopomofo))
    (set-fontset-font (frame-parameter nil 'font)
                      charset
                      (font-spec :family "Microsoft Yahei" :size 12)))

切记不能图省事，直接把 unicode 字符编码集的字体设成中文，这样的话，在 Windows 平台上，原来的英文字体设置就失效了

还有一点，原来对英文字体的设置方法要改成下面这样才能和中文的配合，否则 Emacs 会忽略英文字体的设置 ( 起码在 Windows 平台上是这样 )，所以最终的版本是：

1
2
3
4
5
6
7
8
9

;; Setting English Font
(set-face-attribute
  'default nil :font "Consolas 12")
 
;; Chinese Font
(dolist (charset '(kana han symbol cjk-misc bopomofo))
    (set-fontset-font (frame-parameter nil 'font)
                      charset
                      (font-spec :family "Microsoft Yahei" :size 12)))

字体的选择上，中文我比较喜欢微软雅黑字体，英文的字体我选择等宽字体方便编程。一般常使用 Monaco 或者 Consolas。Monaco 是那种一见倾心型的，字体设计的高挑修长，有种拉丁美人的性感。Consolas 是微软为新的 Visual Studio 专门打造的编程字体，虽然乍看没有 Monaco 那么精艳，可是相当耐看，如同小家碧玉，是个“居家过日子”的实用字体。听说 “DejaVu Sans Mono” 也不错，准备有时间试试看。

到这里，基本上 Emacs 的字体设置算是能赶上其它的编辑器了。可是，做为神一般的编辑器，只是赶上其它编辑器这也太丢人。下面要挑战一下自我，让神器发挥它应有的威力：如何能够根据用户的喜好和操作系统的字体库来做最符合用户心意的字体设定呢？
换言之，我想要的功能是：Emacs 你能不能做到，如果系统有雅黑字体，就请帮忙用雅黑，否则（如 Linux 系统上默认没有雅黑）就请用开源字体文泉驿微米黑。查了一下，网上没有现成的例子，只好挽起袖子，自己研究 elisp 编程动手写了一个设置字体的函数。

首先，我们要能判断某个字体在系统中是否安装:

1
2
3

(defun qiang-font-existsp (font)
  (if (null (x-list-fonts font))
      nil t))

其次，要按顺序找到一个字体列表( list ) 中第一个已经安装可用的字体，下面是个例子

1
2
3

(defvar font-list '("Microsoft Yahei" "文泉驿等宽微米黑" "黑体" "新宋体" "宋体"))
(require 'cl) ;; find-if is in common list package
(find-if #'qiang-font-existsp font-list)

还要有个辅助函数，用来产生带上 font size 信息的 font 描述文本

1
2
3
4
5

(defun qiang-make-font-string (font-name font-size)
  (if (and (stringp font-size) 
           (equal ":" (string (elt font-size 0))))
      (format "%s%s" font-name font-size)
    (format "%s %s" font-name font-size)))

这里绕的地方是，如果传入的 font-size 是“:pixelsize=18”这样的话，字体名称和它之间不能有空格。如果是普通的数字的话（ 12或“12”)，需要有个空格分隔字体名称和字体大小。

有了这些函数，下面出场的就是自动设置字体函数了:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

(defun qiang-set-font (english-fonts
                       english-font-size
                       chinese-fonts
                       &optional chinese-font-size)
  "english-font-size could be set to \":pixelsize=18\" or a integer.
If set/leave chinese-font-size to nil, it will follow english-font-size"
  (require 'cl)                         ; for find if
  (let ((en-font (qiang-make-font-string
                  (find-if #'qiang-font-existsp english-fonts)
                  english-font-size))
        (zh-font (font-spec :family (find-if #'qiang-font-existsp chinese-fonts)
                            :size chinese-font-size)))
 
    ;; Set the default English font
    ;; 
    ;; The following 2 method cannot make the font settig work in new frames.
    ;; (set-default-font "Consolas:pixelsize=18")
    ;; (add-to-list 'default-frame-alist '(font . "Consolas:pixelsize=18"))
    ;; We have to use set-face-attribute
    (message "Set English Font to %s" en-font)
    (set-face-attribute
     'default nil :font en-font)
 
    ;; Set Chinese font 
    ;; Do not use 'unicode charset, it will cause the english font setting invalid
    (message "Set Chinese Font to %s" zh-font)
    (dolist (charset '(kana han symbol cjk-misc bopomofo))
      (set-fontset-font (frame-parameter nil 'font)
                        charset
                        zh-font))))

利用这个函数，Emacs 字体设置就是小菜一碟了

1
2
3

(qiang-set-font
 '("Consolas" "Monaco" "DejaVu Sans Mono" "Monospace" "Courier New") ":pixelsize=18"
 '("Microsoft Yahei" "文泉驿等宽微米黑" "黑体" "新宋体" "宋体"))

这样设置，Emacs 会优先选用 Consolas + “雅黑”的组合。如果“雅黑”没有装的话，就使用“文泉驿等宽微米黑”，依此类推。这份字体配置不用改动就能在不同的操作系统字体环境下面使用，相信应该没有其它编辑器有这么变态的后备字体列表设置了吧。至此，Emacs 在字体设置这方面总算是“体面”地稍稍胜出了其它编辑器。把上面的三个函数加到配置文件 .emacs 里赶快看看效果吧。

Emacs 字体大小的调整

在用 Emacs 做演示或代码审查的时候，经常需要调整默认的字体大小，以前常常为了这个而手忙脚乱。最近才知道，原来 Emacs 默认就有快捷键支持动态调整字体大小：

• 放大字体: Ctrl-x Ctrl-+ 或 Ctrl-x Ctrl-=
• 缩小字体: Ctrl-x Ctrl–
• 重置字体: Ctrl-x Ctrl-0

更酷的是，如果要放大或缩小多次，在第二次直接按 ＋，－，0 就可以了，比如，放大 3 次： Ctrl-x Ctrl-= = = 。另外，Shift + 鼠标左键 也能唤出调整字体大小的弹出菜单。

不过，能不能象网络浏览器和最新版的 Visual Studio 2010 那样，用 Ctrl 加上鼠标滚轮操作来设置字体大小呢，毕竟大部分人已经习惯了这种方式了。既然是无所不能的 Emacs，那当然没问题了，把下面的配置加入 .emacs 里再试试看

1
2
3
4
5
6
7

;; For Linux
(global-set-key (kbd "<C-mouse-4>") 'text-scale-increase)
(global-set-key (kbd "<C-mouse-5>") 'text-scale-decrease)
 
;; For Windows
(global-set-key (kbd "<C-wheel-up>") 'text-scale-increase)
(global-set-key (kbd "<C-wheel-down>") 'text-scale-decrease)

添加删除注释

写程序的，要经常和注释打交道，注释和反注释一段代码是家常便饭。可惜，Emacs 虽然有这个功能，默认的配置却并不好用：

• 注释/反注释这两个功能默认没有绑定快捷键
• 需要先选中一段区域才能调用注释功能，哪怕只想注释/反注释当前行
• 好在有一个 Alt-; 的快捷键，默认绑定了 comment-dwim，能注释/反注释当前激活的区域。如果没有激活区域，就在当前行末加注释

其实 Alt-; 默认绑定的 comment-dwim 已经很理想了，可是，还是不够 dwim ( Do What I Mean )。能不能变成，如果没有激活的区域，就注释/反注释当前行，仅当在行尾的时候才在行尾加注释呢？下面的配置就是参考别人配置写的 “照我说的做”注释函数:

1
2
3
4
5
6
7
8
9
10
11

(defun qiang-comment-dwim-line (&optional arg)
  "Replacement for the comment-dwim command.
If no region is selected and current line is not blank and we are not at the end of the line,
then comment current line.
Replaces default behaviour of comment-dwim, when it inserts comment at the end of the line."
  (interactive "*P")
  (comment-normalize-vars)
  (if (and (not (region-active-p)) (not (looking-at "[ \t]*$")))
      (comment-or-uncomment-region (line-beginning-position) (line-end-position))
    (comment-dwim arg)))
(global-set-key "\M-;" 'qiang-comment-dwim-line)

这样一来，注释和反注释代码的操作只使用一个 Alt-; 键就全部搞定了，Emacs 会心领神会地“照我说的做”。

复制当前行

这是个经常要用到的操作，以前要么老老实实 Mark 当前行的行首和行尾，然后复制。整个按键流程是：

1. Ctrl-a 光标到行首
2. Ctrl-Shift-Space 设置标记
3. Ctrl-e 光标到行尾。如此这一行就被选为激活的区域了
4. Alt-w 复制当前激活的区域

要么按我比较习惯的操作先剪切当前行，再撤消上一次的剪切操作

1. Ctrl-a 光标到行首
2. Ctrl-k 剪切至行屋，该行消失
3. Ctrl-/ 撤消上一次的操作，该行重现

可以看到，方案二比方案一省一次按键，而且 Ctrl 键不用松开。不过，如此基本的操作要按三个键还是太麻烦了，而且方案二会让文件变成被编辑过的状态。其实，可以发挥一下“按我说的做”的精神。为什么不把 Alt-w 变的更聪明一些，当没有激活的区域时就复制当前的一整行呢？ 说做就做:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

;; Smart copy, if no region active, it simply copy the current whole line
(defadvice kill-line (before check-position activate)
  (if (member major-mode
              '(emacs-lisp-mode scheme-mode lisp-mode
                                c-mode c++-mode objc-mode js-mode
                                latex-mode plain-tex-mode))
      (if (and (eolp) (not (bolp)))
          (progn (forward-char 1)
                 (just-one-space 0)
                 (backward-char 1)))))
 
(defadvice kill-ring-save (before slick-copy activate compile)
  "When called interactively with no active region, copy a single line instead."
  (interactive (if mark-active (list (region-beginning) (region-end))
                 (message "Copied line")
                 (list (line-beginning-position)
                       (line-beginning-position 2)))))
 
(defadvice kill-region (before slick-cut activate compile)
  "When called interactively with no active region, kill a single line instead."
  (interactive
   (if mark-active (list (region-beginning) (region-end))
     (list (line-beginning-position)
           (line-beginning-position 2)))))
 
;; Copy line from point to the end, exclude the line break
(defun qiang-copy-line (arg)
  "Copy lines (as many as prefix argument) in the kill ring"
  (interactive "p")
  (kill-ring-save (point)
                  (line-end-position))
                  ;; (line-beginning-position (+ 1 arg)))
  (message "%d line%s copied" arg (if (= 1 arg) "" "s")))
 
(global-set-key (kbd "M-k") 'qiang-copy-line)

上面还多加了一个配置，就是把 Alt-k 设成复制光标所在处到行尾。与 kill-line 的 Ctrl-k 对应。这样一来，如果是要拷贝一整行的话，只要将光标移动到该行任意位置，按下 Alt-w 就行了。如果是复制某个位置到行尾的文字的话，就把光标移到起始位置处，按 Alt-k 。比默认的操作简化了很多。

拷贝代码自动格式化

Emacs 里对代码的格式化支持的非常好，不但可以在编辑的时候自动帮你格式化，还可以选中一块代码，按 Ctrl-Alt-\ 对这块代码重新进行格式化。如果要粘贴一块代码的话，粘贴完了紧接着按 Ctrl-Alt-\ 就可以把新加入的代码格式化好。可是，对于这种粘贴加上重新格式化的机械操作，Emacs 应该可以将它自动化才能配得上它的名气，把下面的代码加到配置文件里，你的 Emacs 就会拥有这种能力了

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21

(dolist (command '(yank yank-pop))
  (eval
   `(defadvice ,command (after indent-region activate)
      (and (not current-prefix-arg)
           (member major-mode
                   '(emacs-lisp-mode
                     lisp-mode
                     clojure-mode
                     scheme-mode
                     haskell-mode
                     ruby-mode
                     rspec-mode
                     python-mode
                     c-mode
                     c++-mode
                     objc-mode
                     latex-mode
                     js-mode
                     plain-tex-mode))
           (let ((mark-even-if-inactive transient-mark-mode))
             (indent-region (region-beginning) (region-end) nil))))))

你可以加入或删除一些 mode 名称来定制上面的配置。

Emacs 与 Windows 系统的整合

在注册表中加入下面的项，右键上下文菜单中就会多出 “Emacs”，你可以使用它快速用 Emacs 编辑任意文件而不用和该文件类型相关联

[HKEY_CLASSES_ROOT\AllFilesystemObjects\Shell\Emacs\command]
@="\"D:\\full\\path\\to\\emacs\\bin\\emacsclientw.exe\" -n -a \"D:\\full\\path\\to\\emacs\\bin\\runemacs.exe\" \"%1\""

这里调用 emacsclientw.exe 是为了使用 server-mode 来避免再打开一个 Emacs 实例，-n 参数指明不需要等待 Emacs (server) 编辑结束就直接返回，-a 指明一个替代品：如果找不到 Emacs server，那就通过 “runemacs.exe ” 启动一个 Emacs 实例来编辑。 不要忘了在 .emacs 里加入 (server-mode 1) 来自动启动 emacs server。

有些工具在使用外部工具时命令行不能带任何参数，遇到这种情况，只能写一个 BATCH 文件把上面的命令包装一下：

D:\full\path\to\emacs\bin\emacsclientw.exe -n -a "D:\full\path\to\emacs\bin\runemacs.exe" %*

如果装了 Visual Studio, 那么，在 Visual Studio 的菜单 Tools 下面可以通过 External Tools 加入一个自定义的外部工具。外部工具的命令可以使用上面定义的 emacsclientw.exe, 参数那栏加上

-n -a "D:\full\path\to\emacs\bin\runemacs.exe" +$(CurLine) $(ItemPath)”

将这个外部工具设上一个方便的快捷键，比如我就设成 Alt-F1，这样每次用 Visual Studio 浏览代码时，如果看到想编辑的内容，直接 Alt-F1 就可以把 Emasc 呼出，光标会自动放在文件刚刚看的那行上面。编辑完了后再 Alt-Tab 就可以切会 Visual Studio 了。你可能还需要设置 Visual Studio 自动重新载入改过的文件，避免每次都弹出对话框让你确认是否重新载入。

Emacs 的配色

我以前的 Emacs 配色非常简单，黑底白字。用的时间长了会腻，而且，Emacs 默认的代码高亮配色只能说相当的一般。

1
2
3
4
5

(setq default-frame-alist
      '((cursor-color . "purple")
        (cursor-type . box)
        (foreground-color . "white")
        (background-color ."black"))

这两天在网上搜 Emacs 相关配置的时候，无意见发现了一个很漂亮的配置。一个好心人用了下 Mac 上的神级编辑器 TextMate。发现里面的 Blackboard 颜色主题很养眼，于是就把这个配色方案写成了一个 color-theme 移到了 Emacs 上，效果相当赞。

我在使用这个主题时做了三处调整

• 变量声明的颜色改为 绿宝石色，与函数声明的颜色相区别
• 背景底色由黑板色改为纯黑色，增加对比度
• 当前行高亮色改为深蓝色(#001)，不让它太明显

下面是我调整后的主题

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

;; Blackboard Colour Theme for Emacs.
;;
;; Defines a colour scheme resembling that of the original TextMate Blackboard colour theme.
;; To use add the following to your .emacs file (requires the color-theme package):
;;
;; (require 'color-theme)
;; (color-theme-initialize)
;; (load-file "~/.emacs.d/themes/color-theme-blackboard.el")
;;
;; And then (color-theme-blackboard) to activate it.
;;
;; MIT License Copyright (c) 2008 JD Huntington 
;; Credits due to the excellent TextMate Blackboard theme
;;
;; All patches welcome
 
(defun color-theme-blackboard ()
  "Color theme by JD Huntington, based off the TextMate Blackboard theme, created 2008-11-27"
  (interactive)
  (color-theme-install
   '(color-theme-blackboard
     (
      ;; (background-color . "#0C1021")
      (background-color . "black")
      (background-mode . dark)
      (border-color . "black")
      (cursor-color . "#A7A7A7")
      (foreground-color . "#F8F8F8")
      (mouse-color . "sienna1"))
     ;; (default ((t (:background "#0C1021" :foreground "#F8F8F8"))))
     (default ((t (:background "black" :foreground "#F8F8F8"))))
     (blue ((t (:foreground "blue"))))
     (bold ((t (:bold t))))
     (bold-italic ((t (:bold t))))
     (border-glyph ((t (nil))))
     (buffers-tab ((t (:background "#0C1021" :foreground "#F8F8F8"))))
     (font-lock-builtin-face ((t (:foreground "#F8F8F8"))))
     (font-lock-comment-face ((t (:italic t :foreground "#AEAEAE"))))
     (font-lock-constant-face ((t (:foreground "#D8FA3C"))))
     (font-lock-doc-string-face ((t (:foreground "DarkOrange"))))
     (font-lock-function-name-face ((t (:foreground "#FF6400"))))
     (font-lock-keyword-face ((t (:foreground "#FBDE2D"))))
     (font-lock-preprocessor-face ((t (:foreground "Aquamarine"))))
     (font-lock-reference-face ((t (:foreground "SlateBlue"))))
 
     (font-lock-regexp-grouping-backslash ((t (:foreground "#E9C062"))))
     (font-lock-regexp-grouping-construct ((t (:foreground "red"))))
 
     (font-lock-string-face ((t (:foreground "#61CE3C"))))
     (font-lock-type-face ((t (:foreground "#8DA6CE"))))
     ;(font-lock-variable-name-face ((t (:foreground "#FF6400"))))
     (font-lock-variable-name-face ((t (:foreground "#40E0D0"))))
     (font-lock-warning-face ((t (:bold t :foreground "Pink"))))
     (gui-element ((t (:background "#D4D0C8" :foreground "black"))))
     (region ((t (:background "#253B76"))))
     (mode-line ((t (:background "grey75" :foreground "black"))))
     ;(highlight ((t (:background "#222222"))))
     (highlight ((t (:background "#001"))))
     (highline-face ((t (:background "SeaGreen"))))
     (italic ((t (nil))))
     (left-margin ((t (nil))))
     (text-cursor ((t (:background "yellow" :foreground "black"))))
     (toolbar ((t (nil))))
     (underline ((nil (:underline nil))))
     (zmacs-region ((t (:background "snow" :foreground "ble")))))))

使用的话需要先安装 color-theme 包，将上面的配色存为 color-theme-blackboard.el 放在 emacs 的 load path 中，在加入下面的配置就好了：

1
2
3
4
5

(require 'color-theme)
(eval-after-load "color-theme"
  '(progn
     (color-theme-initialize)
     (color-theme-blackboard)))

来看看我配置的使用 Consolas + “雅黑” + blackboard-theme的Emacs：

小强的Emacs

虽说10个人会配出 11 种不同的 Emacs，不过我这个还算是芙蓉出水，落落大方吧

折腾到此结束，“整容”过后的 Emacs 更加的漂亮听话了。话说回来，Emacs 实在是要与时俱进，多和苹果学学，改进一下自己难学难用的形象，最好将这些好用的 UI 操作设为默认配置。毕竟对最终用户来说这样的折腾也只能偶尔为之，老是将心思花在配置这神一样的编辑器上面，自己早晚也要成为半仙。

相关日志

• 我的Emacs配置文件 － DEA (164)
• 用CEDET浏览和编辑C++代码 (111)
• Emacs才是世界上最强的IDE – 用w3m浏览网页 (14)
• Emacs长啥样 (1)
• Emacs才是世界上最强大的IDE － 用Emaci阅读文件 (85)

Fast,Cheap,Good: Choose any two.
                                  --anonymous.

#include                                     <math.h>
#include                                   <sys/time.h>
#include                                   <X11/Xlib.h>
#include                                  <X11/keysym.h>
                                          double L ,o ,P
                                         ,_=dt,T,Z,D=1,d,
                                         s[999],E,h= 8,I,
                                         J,K,w[999],M,m,O
                                        ,n[999],j=33e-3,i=
                                        1E3,r,t, u,v ,W,S=
                                        74.5,l=221,X=7.26,
                                        a,B,A=32.2,c, F,H;
                                        int N,q, C, y,p,U;
                                       Window z; char f[52]
                                    ; GC k; main(){ Display*e=
 XOpenDisplay( 0); z=RootWindow(e,0); for (XSetForeground(e,k=XCreateGC (e,z,0,0),BlackPixel(e,0))
; scanf("%lf%lf%lf",y +n,w+y, y+s)+1; y ++); XSelectInput(e,z= XCreateSimpleWindow(e,z,0,0,400,400,
0,0,WhitePixel(e,0) ),KeyPressMask); for(XMapWindow(e,z); ; T=sin(O)){ struct timeval G={ 0,dt*1e6}
; K= cos(j); N=1e4; M+= H*_; Z=D*K; F+=_*P; r=E*K; W=cos( O); m=K*W; H=K*T; O+=D*_*F/ K+d/K*E*_; B=
sin(j); a=B*T*D-E*W; XClearWindow(e,z); t=T*E+ D*B*W; j+=d*_*D-_*F*E; P=W*E*B-T*D; for (o+=(I=D*W+E
*T*B,E*d/K *B+v+B/K*F*D)*_; p<y; ){ T=p[s]+i; E=c-p[w]; D=n[p]-L; K=D*m-B*T-H*E; if(p [n]+w[ p]+p[s
]== 0|K <fabs(W=T*r-I*E +D*P) |fabs(D=t *D+Z *T-a *E)> K)N=1e4; else{ q=W/K *4E2+2e2; C= 2E2+4e2/ K
 *D; N-1E4&& XDrawLine(e ,z,k,N ,U,q,C); N=q; U=C; } ++p; } L+=_* (X*t +P*M+m*l); T=X*X+ l*l+M *M;
  XDrawString(e,z,k ,20,380,f,17); D=v/l*15; i+=(B *l-M*r -X*Z)*_; for(; XPending(e); u *=CS!=N){
                                   XEvent z; XNextEvent(e ,&z);
                                       ++*((N=XLookupKeysym
                                         (&z.xkey,0))-IT?
                                         N-LT? UP-N?& E:&
                                         J:& u: &h); --*(
                                         DN -N? N-DT ?N==
                                         RT?&u: & W:&h:&J
                                          ); } m=15*F/l;
                                          c+=(I=M/ l,l*H
                                          +I*M+a*X)*_; H
                                          =A*r+v*X-F*l+(
                                          E=.1+X*4.9/l,t
                                          =T*m/32-I*T/24
                                           )/S; K=F*M+(
                                           h* 1e4/l-(T+
                                           E*5*T*E)/3e2
                                           )/S-X*d-B*A;
                                           a=2.63 /l*d;
                                           X+=( d*l-T/S
                                            *(.19*E +a
                                            *.64+J/1e3
                                            )-M* v +A*
                                            Z)*_; l +=
                                            K *_; W=d;
                                            sprintf(f,
                                            "%5d  %3d"
                                            "%7d",p =l
                                           /1.7,(C=9E3+
                              O*57.3)%0550,(int)i); d+=T*(.45-14/l*
                             X-a*130-J* .14)*_/125e2+F*_*v; P=(T*(47
                             *I-m* 52+E*94 *D-t*.38+u*.21*E) /1e2+W*
                             179*v)/2312; select(p=0,0,0,0,&G); v-=(
                              W*F-T*(.63*m-I*.086+m*E*19-D*25-.11*u
                               )/107e2)*_; D=cos(o); E=sin(o); } }

//程序在linux下使用以下命令编译：
//cc banks.c -o banks -DIT=XK_Page_Up -DDT=XK_Page_Down \
//  -DUP=XK_Up -DDN=XK_Down -DLT=XK_Left -DRT=XK_Right \
//  -DCS=XK_Return -Ddt=0.02 -lm -lX11 -L/usr/X11R6/lib

+----------+ edit +----------+   input +----------+ compile +----------+
| refined  |<-----+ h,cpp    +-------->+ compiler,+-------->+Executable|
|   h,cpp  |      |          |         | linker   |         |   File   |
+----------+      +----+-----+         +----------+         +----------+
                       | input
                       v
                  +----------+
                  | doxygen  |
                  |          |
                  +----+-----+
                       | process
                       v
                  +----------+
                  | Doxgen   |
                  | Document |
                  +----------+

#+BEGIN_DITAA  asciiExample.png -o -r -S

       +----------+ edit +----------+   input +----------+ compile +----------+
       | refined  |<-----+ h,cpp    +-------->+ compiler,+-------->+Executable|
       |   h,cpp  |      |          |         | linker   |         |   File   |
       +----------+      +----+-----+         +----------+         +----------+
                              | input
                              v
                         +----------+
                         | doxygen  |
                         |          |
                         +----+-----+
                              | process
                              v
                         +----------+
                         | Doxgen   |
                         | Document |
                         +----------+

#+END_DITAA

#+BEGIN_DITAA  asciiExampleWithColor.png -o -r -S

       +----------+ edit +----------+   input +----------+ compile +----------+
       |  cPNK    |      |  cRED    |         |   cGRE   |         |  cPNK    |
       | refined  |<-----+ h,cpp    +-------->+ compiler,+-------->+Executable|
       |   h,cpp  |      |          |         | linker   |         |   File   |
       |          |      |          |         |          |         |          |
       +----------+      +----+-----+         +----------+         +----------+
                              | input
                              v
                         +----------+
                         |  cGRE    |
                         | doxygen  |
                         |          |
                         +----+-----+
                              | process
                              v
                         +----------+
                         |  cPNK    |
                         | Doxgen   |
                         | Document |
                         |          |
                         +----------+

#+END_DITAA

#+BEGIN_DITAA  asciiExampleWithColorAndType.png -o -r -S

       +----------+ edit +----------+   input +----------+ compile +----------+
       |  cPNK    |      |  cRED    |         |   cGRE   |         |  cPNK    |
       | refined  |<-----+ h,cpp    +-------->+ compiler,+-------->+Executable|
       |   h,cpp  |      |          |         | linker   |         |   File   |
       | {s}      |      |  {io}    |         |          |         |    {s}   |
       +----------+      +----+-----+         +----------+         +----------+
                              | input
                              v
                         +----------+
                         |  cGRE    |
                         | doxygen  |
                         |          |
                         +----+-----+
                              | process
                              v
                         +----------+
                         |  cPNK    |
                         | Doxgen   |
                         | Document |
                         |    {d}   |
                         +----------+

#+END_DITAA

#+BEGIN_DITAA  asciiExampleWithColorAndTypeUtf8.png -e gb2312

              +------------+     +------------+
              | 中文        |---->|    中文    |
              |            |     |            |
              +------------+     +------------+

#+END_DITAA

正确显示中文需要文章使用的编码和ditaa指定的编码一致。

相关日志

• 我的Emacs配置文件 － DEA (164)
• 我是如何从vim转向Emacs的 (37)
• ERC使用简介 (34)
• 用CEDET浏览和编辑C++代码 (111)
• 关于 (14)

作者原话：google-maps 是一个emacs的扩展，允许在emacs中显示google地图。

如果想瞻仰生下google-maps-el这个蛋的母鸡，猛击我。

google-maps使用了 Google static Maps API和Google Maps Geocoding API¹。
google-maps-el原作者的效果图：

google-mpas-el如何使用

进入

M-x google-maps

使用

google maps mode下的键绑定，对应命令，相应解释

访问五道口的效果⁵：

实际操作

下面展示了，如何使用google-maps-el来生成以下的效果。
1 M-x google-maps ，在minibuffer中输入:wudaokou, beijing(进入五道口)
2 m Tsinghua RET p(标记清华大学为P)
3 m Peking University RET b(标记北京大学为B)
4 m Qinghuayuan Railway RTT q(标记清华园站为Q)
5 m Zhanchun Bridge RET z(标记展春桥为Z)
结果如下：

想要更炫的如作者展示的一样的结果，请参考作者图片上的设置，可以给marker设置表示颜色，在地图上显示从A地点到B地点的路径⁶。

为什么使用google-maps-el

这个原因不好说，不能说，也说不好。只是这里有两个新闻solidot, 月光博客。

google-maps方便，基于api的也应该更安全吧。

就算没有这些更安全、更方便，闲暇时把google maps搞进emacs，show给别人看，然后暗爽，也算是一种自娱自乐吧，呵呵

1. API 真是个好东西。当我的思维还停留web时代以前，认为API只是库或者框架对外提供的接口，方便库和框架与其他软件交互时，API已经远远超出这个范畴，进入web2.0时代，详细了解web APIS，猛击我。

2. 支持中文，英文，中文拼音。

3. 有四种hybrid(混合地图),roadmap(道路图),satellite(卫星图),terrain(地域图)。

4. 作者效果图中有对visible的设置，应该是有用的，欲了解详细的geeker请读文档代码。

5. hybrid效果。

6. 路径功能，个人感觉不实用，路径需要在配置文件中写，而不能实时查询。感兴趣的童鞋可以扩展此功能:)

相关日志

• 高亮C的所有变量和函数 (43)
• 我的Emacs配置文件 － DEA (164)
• 用CEDET浏览和编辑C++代码 (111)
• Emacs才是世界上最强大的IDE － 用Emaci阅读文件 (85)
• Emacs初学者必知必会 (5)

doxymacs 官网，现在版本是1.8.0。

特性：

• 从emacs中，查找某个符号的文档，显示在你选择的浏览器中。
• 在源代码中方便的插入Doxgen Style格式的注释。
• 可选：实用外部XML parser加速构建完整列表。
• 高亮Doxygen关键字。

特性1,3,4我用的比较少，重点介绍第二个。

安装

Doxymacs 依赖一下包:

W3 http://www.cs.indiana.edu/usr/local/www/elisp/w3/docs.html

tempo http://www.lysator.liu.se/~davidk/elisp/

libxml2 http://www.libxml.org/

将doxymacs.el放到load-path路径下，在.emacs中加入下面语句

(require 'doxymacs)

命令doxymacs-mode就可以启动，如让doxymacs-mode随着c/c++ mode自动启动，

(add-hook 'c-mode-common-hook 'doxymacs-mode)

代码中插入doxygen注释

如果一切正常，那么在启动一个c/c++文件后，就进入了doxymacs-mode。
可以使用以下快捷键：

到此，doxymacs基本就可以工作正常了。
工作流程如下:

      +------------+            +------------+          +------------+
      |  coding    |----------->| commenting |--------->| generating |
      |            |            |            |          | documents  |
      +------------+            +------------+          +------------+

更改默认doxygen注释样式

方便的插入doxygen注释还不是最精彩的，最精彩的当然是用户自定义样式了。

改变默认的doxygen注释类别

这里我们首先修改变量doxymacs-doxygen-style，doxymacs默认是javaDoc，我们把它改为c++。

定制doxygen的注释模板

doxymacs.el中有定义doxymacs-C++-file-comment-template,blablabla。顾名思义，此物就是c++-file-comment的模板。
比如，根据我们公司注释的规定，我在.emacs中加入如下代码:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

(defconst doxymacs-C++-file-comment-template
 '(
   "/******************************************************************************" > n
   "*" > n
   "* " "FILE NAME   :"
   (if (buffer-file-name)
       (file-name-nondirectory (buffer-file-name))
     "") > n
   "*" > n
   "*" " DESCRIPTION :"> n
   "*" > n
   "*" "    "> n
   "*" > n
   "*" " HISTORY     :"> n
   "*" > n
   "*" "    See Log at end of file"> n
   "*" > n
   "*" "Copyright (c) 2006, VIA Technologies, Inc."> n
   "*" "******************************************************************************/"> n)
 "Default C++-style template for file documentation.")

这样，我在test.cpp文件，实用C-c d i，会生成如下代码

1
2
3
4
5
6
7
8
9
10
11
12
13
14

/******************************************************************************
 *
 * FILE NAME   :test.cpp
 *
 * DESCRIPTION :
 *
 *
 *
 * HISTORY     :
 *
 *    See Log at end of file
 *
 *Copyright (c) 2006, VIA Technologies, Inc.
 *******************************************************************************/

如果你使用c++的话，你还有下边几个变量需要定制，

使用其他语言类同。

enjoy!

相关日志

• 用CEDET浏览和编辑C++代码 (111)
• 折腾Emacs (62)
• 我的Emacs配置文件 － DEA (164)
• 介绍一些Emacs功能强大的函数 (18)
• Emacs才是世界上最强的IDE – 用w3m浏览网页 (14)

前几天，emacs@newsmth上jcjbrian发了张他用emacs开发c++的截图，对他的工具栏挺感兴趣，所以向他请教了一下，同时也阅读了相关的info，在我的emacs上加了些自定义的工具栏（下图），在这记录一下以备忘。

emacs的工具栏配置都存放在tool-bar-map这个keymap里，这个keymap跟我们平时用于键绑定的keymap是一样的¹，emacs会根据tool-bar-map的内容自动生成工具栏，如果执行一下下面这段代码，工具栏就没了：

(setq tool-bar-map (make-sparse-keymap))

要自定义工具栏，只需要修改tool-bar-map这个变量就可以了，一般我们可以用tool-bar-add-item这个函数来往tool-bar-map里添加工具项。

tool-bar-add-item的原型是这样的：

(tool-bar-add-item icon def key &rest props)

参数icon设置工具图标，emacs的工具栏可以使用XPM和PBM格式的图标，当emacs 有libxmp支持时会使用XPM格式，没有libxmp库时会寻找PBM格式的图标(Info上还说有XBM格式，我没搞清楚什么情况下使用XBM)。

在etc/images目录下可以看到emacs自带的图标一般都同时有XPM和PBM两种格式，就是为了在没有libxmp库时也能显示工具栏，因为如果我们只有xpm格式的图标而没有libxmp库时，emacs就不在工具栏上显示这个项了。所以我们自己做图标时最好XPM和PBM都准备一份。

icon参数的类型是字符串，只需要传主文件名就可以，扩展名emacs会自己加，比如对图标文件semantic.xpm写成”semantic”。

emacs会在image-load-path下查找图标文件，这个变量的值默认为(“…/etc/images/” data-directory load-path)，就是说它除了查找image目录外还会查找所有的load-path，所以如果我们有自己的图标目录，把它加到image-load-path或者load-path都可以。

图标的大小好像没有限制，emacs本身使用的图标是24×24像素的，如果使用了比它大的图标，整个工具栏会自动扩大。

参数def设置这个工具项被按下的执行什么命令，它的格式跟global-set-key里的command格式是一样的。

参数key用来给这个工具项指定一个key，这个key用于唯一标识这个工具项，所以在同一个keymap里key不能重复。

剩下的参数可以设置一些属性项，具体可以设置哪些属性可以看Info > elisp > Keymaps > Menu Keymaps > Defining Menus > Extended Menu Items。常用的几个属性有：

• :enable 这个属性的值是一个表达式，emacs对这个表达式求值，如果值为nil时，这个工具项会被禁用。

• :visible 这个属性控制这个工具项是否显示，它的类型与:enable是一样的。

• :help 这个属性类型是字符串，当鼠标在工具项上停留时会显示这个字符串。

其余的属性我没用过，也没仔细研究它们用来干什么。

举例来说，如果要添加一个工具项用来执行gdb命令，并且只有在c-mode或者c++-mode时才让它有效，可以这样：

1
2

(tool-bar-add-item "gud/run" 'gdb 'gdb
                   :enable '(memq major-mode '(c++-mode c-mode)))

这样会把gdb这个工具项添加到默认工具栏的最后，如果不想要emacs默认的工具栏，可以先执行(setq tool-bar-map (make-sparse-keymap))把默认的工具栏清空。

我的toolbar配置文件在：http://github.com/meteor1113/dotemacs/blob/master/init-toolbar.el

相关日志

• 用CEDET浏览和编辑C++代码 (111)
• 用CEDET浏览和编辑C++代码(续) – 使用Emacs 23.2内置的CEDET (69)
• 高亮C的所有变量和函数 (43)
• 我的Emacs配置文件 － DEA (164)
• 我是如何从vim转向Emacs的 (37)

1
2
3

(setq mystr "The quick fox jumped quickly.")
(string-match "\\(qu\\)\\(ick\\)"
                   mystr)   =>副作用：将匹配结果存储到match-data中

1
2
3

(match-string 0 mystr)      =>结果为quick，也就是模式匹配的结果
(match-string 1 mystr)      =>结果为qu   ，也就是第一个分组的匹配结果
(match-string 2 mystr)      =>结果为ick  ，也就是第二个分组的匹配结果

(replace-regexp-in-string "/" "\\\\" "d:/gnu/")

1
2
3
4
5

#!/usr/bin/perl
print "please input a raw regexp ,i will generic a emacs style regexp\n";
$str =<STDIN>;
$str =~ s/\\/\\\\/g;
print $str;

1
2
3
4
5
6
7
8

(defvar myhook nil) ;;定义myhook为空表
(add-hook 'myhook '(lambda ()
          (insert "fun1 was called ")))  ;;将这个匿名函数1加入到myhook表中去
 
(add-hook 'myhook '(lambda ()
          (insert "fun2 was called "))) ;;将匿名函数2加入myhook表中去
 
(run-hooks 'myhook) ;; =>执行这条语句会在光标后插入fun2 was called fun1 was called

1
2
3

(setq myhook (cdr myhook))      ;; =>丢弃myhook中的第一个函数
(setq myhook (reverse myhook))  ;; =>将myhook反转，改变函数执行的顺序
(setq myhook nil)               ;; =>将myhook清空

1
2
3
4
5
6
7
8
9
10
11

(defface cyan-face
  '((t :foreground "cyan"))
  "我自定义的cyan face")
 
(defface yellow-face
  '((t :foreground "yellow"))
  "我自定义的yellow face")
 
(defface magenta-face
  '((((class color)) :foreground "magenta"))
  "我自定义的magenta face")

1
2
3
4
5

(add-hook 'outline-minor-mode-hook
          '(lambda ()
             (hi-lock-set-pattern "^\\*[^*]*?$" 'cyan-face)
             (hi-lock-set-pattern "^\\*\\*[^*]*?$" 'yellow-face)
             (hi-lock-set-pattern "^\\*\\*\\*[^*]*?$" 'magenta-face)))

1
2
3
4

(compile "gcc hello.c")
(compile "c++ hello.cpp")
(compile "perl hello.pl")
(compile "d:/python/python25.exe hello.py")

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

;;这个函数就是用来转换路径的
(defun change-to-cygwin-style-path (emacs-style-path-on-w32)
  (let ((full-path emacs-style-path-on-w32))
    (replace-regexp-in-string "\\(\\w+?\\):\\(\\w*\\)" "/cygdrive/\\1\\2" full-path)))
(change-to-cygwin-style-path (buffer-file-name))
 
(defvar my-compile-hook nil)
 
;;这是主函数，按f5执行此函数
(defun my-compile-main-fun ()
  (interactive)
  (run-hooks  'my-compile-hook))
 
;;这个函数用来编译现在用得到的语言写的代码，以后如果要用到其他语言，可以写个函数，然后加入到my-compile-hook中去。
(defun orginal-compile-fun ()
   (let ((mode major-mode)
    (compstr nil))
        (cond ((eq mode 'c-mode)
       (setq compstr (concat "gcc -std=\"c99\" " (change-to-cygwin-style-path (buffer-file-name)))))
      ((eq mode 'c++-mode)
       (setq compstr (concat "c++  " (change-to-cygwin-style-path (buffer-file-name)))))
      ((eq mode 'emacs-lisp-mode)
       (emacs-lisp-byte-compile))
      ((eq mode 'python-mode)
       (setq compstr (concat "python " (buffer-file-name)))
      )
      ((or (eq mode 'cperl-mode) (eq mode 'perl-mode))
       (setq compstr (concat "D:/Perl/bin/perl.exe " (buffer-file-name))))
      )
    (save-buffer)
    (if compstr 
    (compile compstr))))
;;将orginal-compile-fun加入my-compile-hook中
(add-hook 'my-compile-hook 'orginal-compile-fun)
 
;;将my-compile-main-fun 绑定到f5上
(global-set-key [(f5)] 'my-compile-main-fun)

1
2
3
4
5

(add-hook 'my-compile-hook '(lambda ()
                              (if (eq major-mode 'octave-mode)
                                  (progn
                                    (save-buffer)
                                    (compile (concat "octave --silent " (buffer-file-name)))))))

相关日志

• 折腾Emacs (62)
• 我的Emacs配置文件 － DEA (164)
• Emacs初学者必知必会 (5)
• 用eval-after-load避免不必要的elisp包的加载 (19)
• 用CEDET浏览和编辑C++代码 (111)

相关日志

• 高亮C的所有变量和函数 (43)
• 针对Emacs中文本编辑的编程简介 (2)
• 致Emacs初学者 (56)
• 自定义Emacs工具栏 (21)
• 用性感的尾巴highlight-tail标记最近的修改 (34)

简介

最近也是学习缘故，才重新开始使用邮件列表，只是邮箱里的邮件已经堆积如山了。邮件客户端的选择余地很大，有跨平台的 thunderbird，也有 evolution。emacs 上的邮件客户端有强大的 gnus，但是 gnus 的跨平台性不是很好，太依赖 linux 工具，在 windows 上的配置也比较繁琐。gnus 是单线程的程序，感觉作为新闻阅读器更合适。没有选用 mutt 作为客户端，也是配置繁琐所致，曾经尝试过几次但都失败了。

几番搜索比较后，选择了 mew 作为邮件客户端，一如所有的 emacs 的插件，强大和无穷的定制性。

• 强大的过滤器定制，在 mew 中称为 refile。而且 mew 自动 refile 还是比较准确和人性化的。
• mew 是日本人的作品。因此相比 gnus 对 cjk 的支持要完善。
• mew 内建的丰富模式，一共六种，有 summary, virtual meaaage, draft, header, edit, addrbook mode。
• mew 的配色相比 gnus 实在是非常的舒服，也是最初吸引自己的原因。

安装

mew 的安装在 linux 下很简单，如果是 gentoo 的话，可以直接通过命令”emerge app-emacs/mew” 安装。如果是想要自己来管理各个 elisp 拓展，那可以通过 autotools 进行安装，更推荐前者。

mew 在 windows 的安装上比较折腾，不得不说， emacs 在 windows 上使用要辛苦的多。具体的安装可以参考 mew 的文档，如果要使用 mew 的 ssl 加密连接功能，必须要安装 stunnel3 版本，而且需要openssl 的支持。

1
2
3
4

(if (string-equal system-type "windows-nt")
    ;; Note,in windows,you must use replace stunnel4 with stunnel3 version.
    (setq mew-prog-ssl  "C:/Program Files/stunnel/stunnel.exe")
  (setq mew-prog-ssl "/usr/bin/stunnel"))

配置

mew 的 初始化必要代码建议写入 ~/.emacs 文件中，而 mew 单独的配置建议保存在 ~/.mew.el 文件中，mew 在启动时会读取此文件中的配置内容。

初始化配置

安装完之后还需要在 ~/.emacs 文件中加入如下必要代码以告诉 emacs 如何启动 mew。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18

(autoload 'mew "mew" nil t)
(autoload 'mew-send "mew" nil t)
 
;; Optional setup (Read Mail menu for Emacs 21):
(if (boundp 'read-mail-command)
    (setq read-mail-command 'mew))
 
;; Optional setup (e.g. C-xm for sending a message):
(autoload 'mew-user-agent-compose "mew" nil t)
(if (boundp 'mail-user-agent)
    (setq mail-user-agent 'mew-user-agent))
(if (fboundp 'define-mail-user-agent)
    (define-mail-user-agent
      'mew-user-agent
      'mew-user-agent-compose
      'mew-draft-send-message
      'mew-draft-kill
      'mew-send-hook))

帐号设置

对于邮件服务的设置，在 mew 中即被映射为对 mailbox 的设置，mew 中对于邮件的组织是通过 mailbox 完成的。相应的有 3 种类型的 mailbox，分别表示着local/pop/imap/nntp/，即不同的邮件箱对应着不同的邮件协议，通过变量proto 进行设置。

包含邮件的 mailbox 在 mew 中被称为 folder，而 folder 的名称由两部分组成：proto + string。proto 相应的有三种类型，分别以 +/$/%/- 对应着local/pop/imap/nntp, 如 +inbox 即为最典型的 folder。相应的 mew 的文件夹分为两类，本地 folder 和 远程 folder，本地 folder 有四种类型，+inbox/+draft/+quene/+postq。远程 folder 根据协议既可以分为三种类型，$folder/%folder/-folder，如$inbox/%inbox/-fj.mail.reader.mew。

mew 对多账户的支持很好，可以支持 imap/pop3/nntp/local，可以通过 mew-config-alist变量进行非常灵活而强大的设置。如以下即为 gmail 的设置样例。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

(setq mew-config-alist
      '(
         ;; Default fetch mailbox is IMAP
         ("default"
         ("mailbox-type"         . imap)
         ("proto"                . "%")
         ("imap-server"          . "imap.gmail.com")
         ("imap-ssl"             . t)
         ("imap-user"            . "imapuser@gmail.com")
         ("name"                 . "name")
         ("user"                 . "user")
         ("mail-domain"          . "gmail.com")
         ("imap-ssl-port"        . "993")
         ("imap-size"            . 0)
         ("imap-delete"          . t)
         ("smtp-ssl"             . t)
         ("smtp-auth-list"       . ("PLAIN" "LOGIN" "CRAM-MD5")) 
         ("smtp-user"            . "smtpuser@gmail.com")
         ("smtp-server"          . "smtp.gmail.com")
         ("smtp-ssl-port"        . "465"))
 
         ;; mailbox POP3 for mailinglist
         ("mailinglist"
         ("mailbox-type"         . pop)
         ("proto"                . "+")
         ("pop-server"           . "pop.gmail.com")
         ("pop-ssl"              . t)
         ("name"                 . "username")
         ("user"                 . "user")
         ("mail-domain"          . "gmail.com")
         ("pop-auth"             . pass)
         ("pop-user"             . "popuser@gmail.com")
         ("pop-ssl-port"         . "995")
         ("smtp-user"            . "smtpuser@gmail.com")
         ("smtp-ssl"             . t)
         ("smtp-server"          . "smtp.gmail.com")
         ("smtp-ssl-port"        . "465"))
        ))

引用，回复与签名档

mew 可以灵活的设置如何引用邮件上下文，定制引用的格式。mew的引用是由变量mew-cite-fields 控制，有 From，Subject，Date域，具体的引用样式由 mew-cite-format 设置。mew 默认的配置如下：

1
2
3

(defvar mew-cite-fields '("From:" "Subject:" "Date:"))
(defvar mew-cite-format "From: %s\nSubject: %s\nDate: %s\n\n")
(defvar mew-cite-prefix "> ")

如果需要修改为 Gmail 的引用格式，可以只选择 From 和 Date 域，然后修改mew-cite-format 即可。

1
2

(setq mew-cite-fields '("Date:"  "From:"))
(setq mew-cite-format "On %s %s wrote:\n\n")

如何回复，回复的位置，大概是邮件中争论最多的地方。基本上所有邮件的 web客户端，Gmail，outlook 都默认使用上回复(top-posting)，但是邮件列表和新闻组(usenet)提倡下回复(bottom-posting)，在一个社区中使用“错误”的风格，可能被视作严重违反网络礼仪，从而遭致社区成员的激烈反应。可以参考 wiki 和 python的邮件列表规范和礼节。

回到 mew 的设置，通过设置变量 mew-summary-reply-with-citation-position可以选择是使用上回复或是下回复。如果设置为 body，即回复出现在引文之前，名为上回复，如设置为 end，在引文后回复，使用下回复样式。

mew 默认使用的邮件签名档位于 ~/.signature 文件，由变量 mew-signature-file控制，快捷键 ‘C-cTAB’ 会在光标处插入签名档。建议将签名档放置在邮件的末尾，可以通过 mew-signature-as-lastpart’ 与 ‘mew-signature-insert-last’设置。如果需要在撰写或是回复邮件时，需要自动插入签名档，可以通过mew-draft-mode-newdraft-hook 进行插入。

1
2
3
4
5

(setq mew-signature-file "~/Mail/signature")
(setq mew-signature-as-lastpart t)
(setq mew-signature-insert-last t)
(add-hook 'mew-before-cite-hook 'mew-header-goto-body)
(add-hook 'mew-draft-mode-newdraft-hook 'mew-draft-insert-signature)

refile

对于邮件列表和新闻组，邮件过滤和 thread 功能是不可或缺的。mew 的邮件过滤功能，或是 mew 的术语称谓的 refile 很强大而实用。refile 功能对于pop 邮箱而言非常实用，gmail 的 imap 由于可以使用 filter 与 label 的组合，也非常的完美。

如果为设置任何的 refile rules，在 summary-mode 里面按 o 即可对当前邮件进行分类，mew 会问你把邮件分类到哪个文件夹里面去，并提供了一个默认的选项，通常情况下默认选项就是正确的选项，所以直接回车就可以了。

虽然 mew 的 refil-by-guess 很方便，但是更加使用的还是自定义 refile rules。
mew 提供的 refile 非常丰富，但感觉实用可定性好的还是 Guess by user defined rules。例如，如果你订阅了 octave，freebsd 的帮助邮件列表，很自然的会需要把此三个邮件列表的邮件分开存放在不同的本地文件下，而通常的邮件会存放到 inbox folder。相应的只需要把邮件头的 To 和 Cc 域里包含有 “@octave.org”的邮件 refile 到 +math/octave 文件夹中，同时把 To 和 Cc 域里含有”@freebsd.org”的邮件 refile 到 +unix/freebsd，就可以使用如下的实例代码。
更详尽的 refile rules 可以参考 mew 的使用手册。

1
2
3
4
5
6
7
8
9
10
11

(setq mew-refile-guess-alist
      '(("To:"
         ("@octave.org"                       . "+math/octave")
         ("@freebsd.org"                      . "+unix/freebsd"))
        ("Cc:"
         ("@octave.org"                       . "+math/octave")
         ("@freebsd.org"                      . "+unix/freebsd"))
        (nil . "+inbox")))
(setq mew-refile-guess-control
      '(mew-refile-guess-by-folder
        mew-refile-guess-by-alist))

完成 refile rules 后，在收取邮件后，按下 ‘M-o’ 即可对当前 mode 下的邮件按照定义的 rules 进行 refile。然后，你想要查阅 octave 邮件列表，只需要按下 ‘g’ 与 ‘+math/octave’，就可以切换到 octave 文件夹，此时再按下 ‘tt’，既可以进入 mew 提供的 thread 功能，此时的 mode 称为 virtual folder mode，mew 会指示出各个邮件之间的层次关系，非常方便。

使用folder

在邮件服务设置完成后，就需要获取远程的邮件到本地的 +inbox folder。当输入’M-x mew’，mew 会依据 ‘mew-mailbox-type’ 获取相应协议的邮件。但此时 位于summary 模式时，只需输入 ‘i’ 即可。如果用 mew 处理邮件一段时间后，需要再查收远程 folder 上的邮件，试试 ’s’ 快捷键。对于 IMAP 和 NetNews，更加建议使用 ’s’，而非 ‘i’。当按下 ’s’ 时，mew 会向你询问 range，一般而言输入’sync’ 比较合适，这会同步本地 folder，即删除已在远程服务器上删除的邮件和收取新接受的邮件。当使用 ‘C-u s’快捷键时，可以在仅获取邮件头和获取完整邮件信息间切换，相应的这是由诸如 ‘mew-pop-header-only’ 变量定义的。对于邮件列表和新闻组而言，跟推荐获取完整的邮件信息，刻意离线查阅，非常方便。

使用 Gmail IMAP 非常方便，使用 mew 配合 Gmail 的 filter 与 label 可以对邮件进行很有效的管理。如你当下在 %inbox，如果需要切换到 ‘All sent’，只需要输入 ‘g’，然后输入 ‘%[Gmail]/All Mail’ 或者使用 mew 提供方便的自动补全机制。mew 使用 folder 管理邮件，而在各个 folder 进行切换的快捷键既是方便的 ‘g’。

mew 也提供了方便的对多账户进行使用与切换的功能。以如上的账户设置为例，在如上设置了两个 “cases”: “default”,”mailinglist”。如果当前的 case 为dafault， mew 即为按照 default 的设置，即此时以 imapuser 按照 IMAP 协议收取邮件。而如果你想要切换至 mailinglist 时，只需要使用快捷键 ‘C’，输入mailinglist 即可，此时 mew 即会使用 popuser 帐号以 pop 协议收取邮件。在启动 mew 时，默认使用 default 此 case。

快捷键

mew 的日常使用可以通过各种 mode 上的菜单完成，但使用快捷键也非常方便。

相关日志

• 致Emacs初学者 (56)
• 用CEDET浏览和编辑C++代码 (111)
• 我的Emacs配置文件 － DEA (164)
• Emacs初学者必知必会 (5)
• 用CEDET浏览和编辑C++代码(续) – 使用Emacs 23.2内置的CEDET (69)

概述

artist是一个emacs的内置lisp包。
在artist-mode中，你可以使用鼠标或者键盘来画线(可以带箭头)、矩形、正方形、多边形、椭圆、圆和一些类似于水蒸气似的不规则图形，当然可以擦除，填出图形，还可以在其上写字。

截图

这是一个很不错的绘制单链表的截图flash

这是一个画了一些形状的截图, 这幅图画了一个A.

这是我工作时的一个绘制结果.

为什么使用Artist-mode

我经常在写程序的时候，希望在文档里画一些类的继承关系、包含关系什么的，以帮助读这个文件的人能够更好的理解代码，但是此处不能且不适合放一张jpg（要是h,cpp文件里能插图，那多拉风啊）。

就考虑用plain-text的文本格式来绘图。初始时想用“-|+_”这几个符号来拼凑，但是工作效率太低，而且容易出错，一修改就几乎整个图作废。将有限的时间浪费在如此耗时，且没有技术含量的工作上，那还不就等于浪费生命啊，剩下来的时间多去看看twitter多好！

正如截图中绘制单链表的截图flash所展示，artist-mode来做这件事情，那是最适合不过了。那么来初探一下emacs的artist-mode能够如何完成任务呢。

怎么使用Mouse 绘制

进入artist-mode

M-x artist-mode

离开artist-mode

M-x artist-mode-off

三个mouse

mouse-2（鼠标中键）,shift mouse-2

弹出一个菜单，从菜单里你可以选择要使用左键画什么类型更改一些设定

mouse-1 ( 鼠标左键) , shift-mouse-1

绘制部分由鼠标左键完成，请参考绘制操作。

mouse-3 ( 鼠标右键) , shift mouse-3

绘制操作（鼠标左键）

一些说明

直线：只能是垂直，水平，对角线

箭头：绘制线，或多边形时，可以设置箭头，详细见箭头.

设定

箭头

在artist-mode中，有下面两个键

< artist-toggle-first-arrow > artist-toggle-second-arrow

就像他们的快捷键所展示，artist-toggle-first-arrow将一条直线的第一个字符变为<，而artist-toggle-second-arrow将一条线的最后一个字符变为>。

命令

基本命令

artist-key-set-point 执行的功能

箭头命令

选择操作

有了以上的介绍，我将所有artist-mode的命令绘制为一张表格，再参考artist-mode的键绑定+自己绑定，键盘绘制会像用鼠标绘制一样顺手。

artist变身

或许有人觉得artist-mode绘制出来的ascii图很不错，但是如果能变成图片或许更好；或者图片是一种硬性要求；或者由于不知道的原因，总有可能有需求将ascii变成图片呢？多一种选择总是好事。

好吧，传送门 。

1. 我试验，此处并没有绘制正方形，难道是我的版本有问题，求确认。

2. 与¹相同，我仍然没有得到圆，得到的是椭圆

3. 顾名思义，很拉风的东西，但是我感觉不实用

相关日志

• 我的Emacs配置文件 － DEA (164)
• Emacs中绘图 － ditaa篇 (26)
• 高亮C的所有变量和函数 (43)
• 自定义Emacs工具栏 (21)
• 用CEDET浏览和编辑C++代码 (111)

2 有图为证, 图个痛快

zjl-c-hl效果截图

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23

(defcustom zjl-c-hl-c-mode-enable-flag t
    "*Enable c mode highlight when zjl-c-hl-disable-global-all is called"
     'zjl-c-hl)
(defcustom zjl-c-hl-c++-mode-enable-flag t
    "*Enable c++ mode highlight when zjl-c-hl-disable-global-all is called.
Currently only c style file but named as *.cpp is supported"
    :type 'boolean :group 'zjl-c-hl)
(defcustom zjl-c-hl-normal-size 40000
    "*The size of erea that zjl-c-hl can highlight without any delay.
You can improve this if your computer has enough performance."
    :type 'integer :group 'zjl-c-hl)
(defcustom zjl-c-hl-toobig-size 10000000
    "*The threshold size of function that zjl-c-hl will stop to highlight since it is too big. "
    :type 'integer :group 'zjl-c-hl)
(defcustom zjl-c-hl-toobig-not-update-size 1000000
    "*The size of function that zjl-chl will stop to  highlight when the function is modified."
    :type 'integer :group 'zjl-c-hl)
(defcustom zjl-c-hl-numberofscreen-to-hl-each-time 2
    "*The number of screens around current screen to highlight every time."
    :type 'integer :group 'zjl-c-hl)
(defcustom zjl-c-hl-firstscreen-hl-toggle nil
    "*When not nil and when you open a new buffer, hl buffer before it shown on window."
    :type 'boolean :group 'zjl-c-hl)

1
2
3
4

(font-lock-add-keywords
     mode
     zjl-c-hl-c-mode-keywords
     1)

相关日志

• 我的Emacs配置文件 － DEA (164)
• 用CEDET浏览和编辑C++代码 (111)
• 用CEDET浏览和编辑C++代码(续) – 使用Emacs 23.2内置的CEDET (69)
• Emacs才是世界上最强的IDE － 高亮光标处单词 (19)
• Emacs长啥样 (1)